OLED 1.3" с интерфейсом I2C или точечная сварка - версия Плюс (часть 2: схема, софт)

Прошлый мой обзор про изготовление аппарата точечной сварки вызвал немалый интерес. У людей осталось много вопросов: про детальки, схему, софт… И я решил сделать еще один обзор, в котором опишу все, что вызвало интерес. Любителей самоделок, программирования и схем приглашаю под кат…

К сожалению, сейчас очень плотный график и мне не удалось внести существенных правок в программу, но зато удалось выкроить время на описание (данный обзор).

Предмет обзора приехал в таком пакетике:

Внутри сам экранчик, защищенный предохранительной транспортировочной пленкой:

Обратная сторона:

Размеры:


Для связи с внешним миром экранчик имеет 4 контакта: SDA, SCL, GND, VCC. Соответственно, GND следует соединить с землей, на VCC подать +5 вольт, SDA и SCL — следует подключить к шине I2C. Пример подключения к Arduino UNO:


Для работы с экранчиком я попытался использовать библиотеки от Adafruit (Adafruit GFX Adafruit GFX и Adafruit SSD1306 Adafruit SSD1306) — экранчик показывал шум. Ранее такой же экранчик 0.96" с этими библиотеками отлично работал, требовалось только при инициализации заменить

display.begin(SSD1306_SWITCHCAPVCC, 0x3D);

на

display.begin(SSD1306_SWITCHCAPVCC, 0x3C);

С экранчиком заработала библиотека u8glib. Единственное, изображение было со смещением на пару пикселей. Поковырявшись с библиотекой, поправил файлик u8g_dev_ssd1306_128x64.c и стало все хорошо.

У меня в коде оно используется так:

#include <U8glib.h>

// display 
U8GLIB_SSD1306_128X64 u8g(U8G_I2C_OPT_NONE);

////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
// Show current display
////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
void drawScreen() {
 u8g.firstPage();
 do {
  u8g.setFont(u8g_font_unifont);
  u8g.drawStr( 10, 20, "spot welding");  
  u8g.drawStr( 30, 40, " control");
  u8g.drawStr( 35, 60, " from yurok");
 } while( u8g.nextPage() );
}

Теперь к применению. Схема платы сварки выглядит следующим образом:

Рисовал быстро, без художеств, времени к сожалению сейчас на красоту не хватает. Зато постарался изобразить все понятно.

На схеме показано как управляется включение трансформатора, реле, вентилятора. Указано питание контроллера и описанная ранее схема синхронизации с нулевым напряжением.

Для контроля температуры в этот раз я решил использовать термистор на 100 КОм:


Лучше всего конечно составить таблицу и производить многократные измерения, но для простого варианта, когда не нужна большая точность, можно использовать приведенный подход. Уравнение Стейнхарта-Харта и основанная на нем модель нам вполне подойдут. Снимаем 3 точки сопротивления и температуры, собрав нехитрую конструкцию:

Составляем базу данных показаний :):

Для получнния разных температур я использовал паяльник с жалом Т12, контролируя показания термопарой мультиметра.
Рассчитать параметры A, B, C можно с помощью калькулятора, по трем точкам. Вот мои:

Итог в виде кода:

const byte thermistorPin = A1; // thermistor
// current temperature
double currentTemp = 0;

void setup() {
  Serial.begin(9600);
  Serial.println(F("Start init"));
}

void loop() {
  get_temp();
  Serial.print("Temp:");
  Serial.println(currentTemp);
  delay(1000);
}

////////////////////////////////////
// get temperature from thermister
////////////////////////////////////
void get_temp(){
  int RawADC = analogRead(thermistorPin);
  long Resistance;
  // Assuming a 100k Thermistor.  Calculation is actually: Resistance = (1024/ADC)
  Resistance=((102400000/RawADC) - 100000);
  /******************************************************************/
  /* Utilizes the Steinhart-Hart Thermistor Equation:               */
  /* Temperature in Kelvin = 1 / {A + B[ln®] + C[ln®]^3}        */
  /* where:                                                         */
  /* A = 0,008968616293, B = -0,001212423355 and C = 0,000005416095 */
  /******************************************************************/
  currentTemp = log(Resistance);
  currentTemp = 1 / (0.008968616293 + (-0.001212423355 * currentTemp) + (0.000005416095 * currentTemp * currentTemp * currentTemp));
  // convert Kelvin to Celsius
  currentTemp = currentTemp - 273.15;
}

Проверяем:

Конечно погрешность есть, но нам не требуется точно — так, что вполне норм.

Термистор подключен так:


Следующий интересный элемент нашей сварки — энкодер. Я использовал самый распространенный KY-040:


Размеры:




Я не буду писать кучу теории по нему и прочего… Сугубо практическая информация. В программе нам потребуется распознать вращение влево или вправо, длинное и короткое нажатие на регулятор энкодера. Для этого нам нужно выход CLK и DT подключить к выводом контроллера поддерживающим прерывания (D2 и D3 для Arduino). Выход сигнала нажатия SW — можно подключить на любой цифровой вход контроллера.
Вот так обрабатывается:

// encoder pin and interrupt
const byte encoder_A_Pin = 3;
const byte encoder_B_Pin = 2;
const byte encoderButtonPin = 4;
const byte interruptA = 1;
const byte interruptB = 0;

boolean encoder_rotate = false;
// last state encoder A pin
boolean currentA = false;              
// last state encoder B pin
boolean currentB = false;

// Timeout for different long and short button on
const unsigned long timoutHoldButton = 9000; // 9 sec
// Timeout for bounce protect encoder button
const unsigned long debounceEncButton = 20; // 20 ms
// Time on encoder button
unsigned long timeOnEncButton = 0;
// Time off encoder button
unsigned long timeOffEncButton = 0;
unsigned int buttonEncCurrentVal = HIGH;
unsigned int buttonEncLastVal = HIGH;
boolean ignoreEncOff = false; 

void setup() {
  // encoder init
  pinMode(encoder_A_Pin, INPUT);
  digitalWrite(encoder_A_Pin, HIGH); 
  pinMode(encoder_B_Pin, INPUT); 
  digitalWrite(encoder_B_Pin, HIGH); 
  pinMode(encoderButtonPin, INPUT);
  digitalWrite(encoderButtonPin, HIGH);
  // enable encoder change interrupt
  attachInterrupt(interruptA, onA, CHANGE);
  attachInterrupt(interruptB, onB, CHANGE);
}

////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
// increment rotate
////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
void onA(){
  if (encoder_rotate) delay (1);
  if (digitalRead(encoder_A_Pin) != currentA ) {
    currentA = !currentA;
    if ( currentA && !currentB ) {
         Serial.println("+ encoder");
    }
    encoder_rotate = false;
  }
}

////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
// decrement rotate
////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
void onB(){
  if ( encoder_rotate ) delay (1);
  if( digitalRead(encoder_B_Pin) != currentB ) {
    currentB = !currentB;
    if( currentB && !currentA ){
          Serial.println("- encoder");
    }
    encoder_rotate = false;
 }
}

////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
// main loop
////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
void loop() {
  CurrentTime = millis();

////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
// ENCODER BUTTON
  encoder_rotate = true;
  buttonEncCurrentVal = digitalRead(encoderButtonPin);

  // Test for button pressed and store the down time
  if (buttonEncCurrentVal == LOW && buttonEncLastVal == HIGH && (CurrentTime - timeOffEncButton) > long(debounceEncButton)){
    timeOnEncButton = CurrentTime;
  }
  // Test for button release and store the up time
  if (buttonEncCurrentVal == HIGH && buttonEncLastVal == LOW && (CurrentTime - timeOnEncButton) > long(debounceEncButton)){
    if (ignoreEncOff == false){
        Serial.println(F("short enc"));
    }else{
      ignoreEncOff = false;
    }
    timeOffEncButton = CurrentTime;
  }
  // Test for button held down for longer than the hold time
  if (buttonEncCurrentVal == LOW && (CurrentTime - timeOnEncButton) > long(timoutHoldButton)){
    Serial.println(F("long enc"));
    ignoreEncOff = true;
    timeOnEncButton = CurrentTime;
  }
  buttonEncLastVal = buttonEncCurrentVal;
}

Как видно из кода, предусмотрено распознавание поворота влево и вправо, путем вызова функции по прерыванию. Также реализовано распознавание короткого и длинного нажатия на на энкодер, причем с защитой от дребезга контактов.

Остальные моменты можно будет глянуть в тексте самой программы, я основное старался комментировать.

Напомню, что в итоге у меня получилось так:


Я заказал платы для сварочного аппарата в Китае (много людей обратились с просьбой изготовить, прошить и выслать им такую), пока еще не все разобрали, желающие пишите в личку.

Спасибо всем, кто дочитал этот обзор до конца, надеюсь кому-то данная информация окажется полезной. всем крепких соединений и добра!

Желающие скачать программу могут взять этот файл. Конечно, это только черновик и позже программа станет существенно лучше. Желающие скачать плату также могут это проделать. Раздача печенюшек :).

Продолжение обзора устройства сварки — тут.